source: palm/tags/release-5.0/SOURCE/init_pegrid.f90 @ 3986

Last change on this file since 3986 was 2696, checked in by kanani, 6 years ago

Merge of branch palm4u into trunk

  • Property svn:keywords set to Id
File size: 49.6 KB
Line 
1!> @file init_pegrid.f90
2!------------------------------------------------------------------------------!
3! This file is part of the PALM model system.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2017 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! ------------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: init_pegrid.f90 2696 2017-12-14 17:12:51Z Giersch $
27! 3D-Integer exchange on multigrid level (MS)
28! Forcing implemented (MS)
29!
30! 2600 2017-11-01 14:11:20Z raasch
31! calculation of block-I/O quantitites removed (is now done in parin)
32!
33! 2516 2017-10-04 11:03:04Z suehring
34! Remove tabs
35!
36! 2514 2017-10-04 09:52:37Z suehring
37! Redundant preprocessor directives removed
38!
39! 2372 2017-08-25 12:37:32Z sward
40! Shifted cyclic boundary conditions implemented
41!
42! 2365 2017-08-21 14:59:59Z kanani
43! Vertical nesting implemented (SadiqHuq)
44!
45! 2300 2017-06-29 13:31:14Z raasch
46! host-specific settings removed
47!
48! 2298 2017-06-29 09:28:18Z raasch
49! MPI2 related parts removed
50!
51! 2271 2017-06-09 12:34:55Z sward
52! Error message changed
53!
54! 2259 2017-06-08 09:09:11Z gronemeier
55! Implemented synthetic turbulence generator
56!
57! 2238 2017-05-31 16:49:16Z suehring
58! Remove unnecessary module load of pmc_interface
59!
60! 2231 2017-05-30 16:44:33Z suehring
61!
62! 2200 2017-04-11 11:37:51Z suehring
63! monotonic_adjustment removed
64!
65! 2197 2017-03-24 02:25:00Z raasch
66! bugfix: do not allow odd values for nz at the coarsest grid level in case of
67! optimized multigrid solver
68!
69! 2180 2017-03-17 13:33:05Z hellstea
70! Checks to ensure (2178) that pdims match the grid dimensions in the
71! automatic determination of pdims are canceled as unnecessary
72!
73! 2178 2017-03-17 11:07:39Z hellstea
74! Checks to ensure that pdims match the grid dimensions are added in the
75! automatic determination of pdims
76!
77! 2050 2016-11-08 15:00:55Z gronemeier
78! Implement turbulent outflow condition
79!
80! 2000 2016-08-20 18:09:15Z knoop
81! Forced header and separation lines into 80 columns
82!
83! 1968 2016-07-18 12:01:49Z suehring
84! Extent MPI-datatypes for exchange of 2D-INTEGER arrays on coarser multigrid
85! level 
86!
87! 1964 2016-07-14 15:35:18Z hellstea
88! Bugfix: erroneous setting of nest_bound_l/r/s/n = .TRUE. for vertical nesting mode removed.
89!
90! 1923 2016-05-31 16:37:07Z boeske
91! Initial version of purely vertical nesting introduced.
92!
93! 1922 2016-05-31 16:36:08Z boeske
94! Bugfix: array transposition checks restricted to cases if a fourier
95! transform is used , removed unused variable nnx_z
96!
97! 1833 2016-04-07 14:23:03Z raasch
98! spectra related variables moved to spectra_mod
99!
100! 1815 2016-04-06 13:49:59Z raasch
101! cpp-directives for intel openmp bug removed
102!
103! 1804 2016-04-05 16:30:18Z maronga
104! Removed code for parameter file check (__check)
105!
106! 1779 2016-03-03 08:01:28Z raasch
107! changes regarding nested domain removed: virtual PE grid will be automatically
108! calculated for nested runs too
109!
110! 1764 2016-02-28 12:45:19Z raasch
111! cpp-statements for nesting removed
112!
113! 1762 2016-02-25 12:31:13Z hellstea
114! Introduction of nested domain feature
115!
116! 1682 2015-10-07 23:56:08Z knoop
117! Code annotations made doxygen readable
118!
119! 1677 2015-10-02 13:25:23Z boeske
120! New MPI-data types for exchange of 3D integer arrays.
121!
122! 1575 2015-03-27 09:56:27Z raasch
123! adjustments for psolver-queries, calculation of ngp_xz added
124!
125! 1565 2015-03-09 20:59:31Z suehring
126! Refine if-clause for setting nbgp.
127!
128! 1557 2015-03-05 16:43:04Z suehring
129! Adjustment for monotonic limiter
130!
131! 1468 2014-09-24 14:06:57Z maronga
132! Adapted for use on up to 6-digit processor cores
133!
134! 1435 2014-07-21 10:37:02Z keck
135! bugfix: added missing parameter coupling_mode_remote to ONLY-attribute
136!
137! 1402 2014-05-09 14:25:13Z raasch
138! location messages modified
139!
140! 1384 2014-05-02 14:31:06Z raasch
141! location messages added
142!
143! 1353 2014-04-08 15:21:23Z heinze
144! REAL constants provided with KIND-attribute
145!
146! 1322 2014-03-20 16:38:49Z raasch
147! REAL functions provided with KIND-attribute
148!
149! 1320 2014-03-20 08:40:49Z raasch
150! ONLY-attribute added to USE-statements,
151! kind-parameters added to all INTEGER and REAL declaration statements,
152! kinds are defined in new module kinds,
153! revision history before 2012 removed,
154! comment fields (!:) to be used for variable explanations added to
155! all variable declaration statements
156!
157! 1304 2014-03-12 10:29:42Z raasch
158! bugfix: single core MPI runs missed some settings of transpose indices
159!
160! 1212 2013-08-15 08:46:27Z raasch
161! error message for poisfft_hybrid removed
162!
163! 1159 2013-05-21 11:58:22Z fricke
164! dirichlet/neumann and neumann/dirichlet removed
165!
166! 1139 2013-04-18 07:25:03Z raasch
167! bugfix for calculating the id of the PE carrying the recycling plane
168!
169! 1111 2013-03-08 23:54:10Z raasch
170! initialization of poisfft moved to module poisfft
171!
172! 1092 2013-02-02 11:24:22Z raasch
173! unused variables removed
174!
175! 1056 2012-11-16 15:28:04Z raasch
176! Indices for arrays n.._mg start from zero due to definition of arrays f2 and
177! p2 as automatic arrays in recursive subroutine next_mg_level
178!
179! 1041 2012-11-06 02:36:29Z raasch
180! a 2d virtual processor topology is used by default for all machines
181!
182! 1036 2012-10-22 13:43:42Z raasch
183! code put under GPL (PALM 3.9)
184!
185! 1003 2012-09-14 14:35:53Z raasch
186! subdomains must have identical size (grid matching = "match" removed)
187!
188! 1001 2012-09-13 14:08:46Z raasch
189! all actions concerning upstream-spline-method removed
190!
191! 978 2012-08-09 08:28:32Z fricke
192! dirichlet/neumann and neumann/dirichlet added
193! nxlu and nysv are also calculated for inflow boundary
194!
195! 809 2012-01-30 13:32:58Z maronga
196! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
197!
198! 807 2012-01-25 11:53:51Z maronga
199! New cpp directive "__check" implemented which is used by check_namelist_files
200!
201! Revision 1.1  1997/07/24 11:15:09  raasch
202! Initial revision
203!
204!
205! Description:
206! ------------
207!> Determination of the virtual processor topology (if not prescribed by the
208!> user)and computation of the grid point number and array bounds of the local
209!> domains.
210!> @todo: remove MPI-data types for 2D exchange on coarse multigrid level (not
211!>        used any more)
212!------------------------------------------------------------------------------!
213 SUBROUTINE init_pegrid
214 
215
216    USE control_parameters,                                                    &
217        ONLY:  bc_lr, bc_ns, coupling_mode, coupling_mode_remote,              &
218               coupling_topology, force_bound_l, force_bound_n, force_bound_r, &
219               force_bound_s, gathered_size, grid_level,                       &
220               grid_level_count, inflow_l, inflow_n, inflow_r, inflow_s,       &
221               maximum_grid_level, message_string,                             &
222               mg_switch_to_pe0_level, momentum_advec, nest_bound_l,           &
223               nest_bound_n, nest_bound_r, nest_bound_s, nest_domain, neutral, &
224               psolver, outflow_l, outflow_n, outflow_r, outflow_s,            &
225               outflow_source_plane, recycling_width, scalar_advec,            &
226               subdomain_size, turbulent_outflow, y_shift
227
228    USE grid_variables,                                                        &
229        ONLY:  dx
230       
231    USE indices,                                                               &
232        ONLY:  mg_loc_ind, nbgp, nnx, nny, nnz, nx, nx_a, nx_o, nxl, nxl_mg,   &
233               nxlu, nxr, nxr_mg, ny, ny_a, ny_o, nyn, nyn_mg, nys, nys_mg,    &
234               nysv, nz, nzb, nzt, nzt_mg, wall_flags_1, wall_flags_2,         &
235               wall_flags_3, wall_flags_4, wall_flags_5, wall_flags_6,         &
236               wall_flags_7, wall_flags_8, wall_flags_9, wall_flags_10
237
238    USE kinds
239     
240    USE pegrid
241     
242    USE spectra_mod,                                                           &
243        ONLY:  calculate_spectra, dt_dosp
244
245    USE synthetic_turbulence_generator_mod,                                    &
246        ONLY:  use_synthetic_turbulence_generator
247
248    USE transpose_indices,                                                     &
249        ONLY:  nxl_y, nxl_yd, nxl_z, nxr_y, nxr_yd, nxr_z, nyn_x, nyn_z, nys_x,&
250               nys_z, nzb_x, nzb_y, nzb_yd, nzt_x, nzt_yd, nzt_y
251
252    USE vertical_nesting_mod,                                                  &
253        ONLY:  vnested, vnest_init_pegrid_domain, vnest_init_pegrid_rank
254
255    IMPLICIT NONE
256
257    INTEGER(iwp) ::  i                        !<
258    INTEGER(iwp) ::  id_inflow_l              !<
259    INTEGER(iwp) ::  id_outflow_l             !< local value of id_outflow
260    INTEGER(iwp) ::  id_outflow_source_l      !< local value of id_outflow_source
261    INTEGER(iwp) ::  id_recycling_l           !<
262    INTEGER(iwp) ::  ind(5)                   !<
263    INTEGER(iwp) ::  j                        !<
264    INTEGER(iwp) ::  k                        !<
265    INTEGER(iwp) ::  maximum_grid_level_l     !<
266    INTEGER(iwp) ::  mg_levels_x              !<
267    INTEGER(iwp) ::  mg_levels_y              !<
268    INTEGER(iwp) ::  mg_levels_z              !<
269    INTEGER(iwp) ::  mg_switch_to_pe0_level_l !<
270    INTEGER(iwp) ::  nnx_y                    !<
271    INTEGER(iwp) ::  nnx_z                    !<
272    INTEGER(iwp) ::  nny_x                    !<
273    INTEGER(iwp) ::  nny_z                    !<
274    INTEGER(iwp) ::  nnz_x                    !<
275    INTEGER(iwp) ::  nnz_y                    !<
276    INTEGER(iwp) ::  numproc_sqr              !<
277    INTEGER(iwp) ::  nxl_l                    !<
278    INTEGER(iwp) ::  nxr_l                    !<
279    INTEGER(iwp) ::  nyn_l                    !<
280    INTEGER(iwp) ::  nys_l                    !<
281    INTEGER(iwp) ::  nzb_l                    !<
282    INTEGER(iwp) ::  nzt_l                    !<
283    INTEGER(iwp) ::  omp_get_num_threads      !<
284
285    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  ind_all !<
286    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxlf    !<
287    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxrf    !<
288    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nynf    !<
289    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nysf    !<
290
291    INTEGER(iwp), DIMENSION(2) ::  pdims_remote         !<
292    INTEGER(iwp)               ::  lcoord(2)            !< PE coordinates of left neighbor along x and y
293    INTEGER(iwp)               ::  rcoord(2)            !< PE coordinates of right neighbor along x and y
294
295!
296!-- Get the number of OpenMP threads
297    !$OMP PARALLEL
298!$  threads_per_task = omp_get_num_threads()
299    !$OMP END PARALLEL
300
301
302#if defined( __parallel )
303
304    CALL location_message( 'creating virtual PE grids + MPI derived data types', &
305                           .FALSE. )
306
307!
308!-- Determine the processor topology or check it, if prescribed by the user
309    IF ( npex == -1  .AND.  npey == -1 )  THEN
310
311!
312!--    Automatic determination of the topology
313       numproc_sqr = SQRT( REAL( numprocs, KIND=wp ) )
314       pdims(1)    = MAX( numproc_sqr , 1 )
315       DO  WHILE ( MOD( numprocs , pdims(1) ) /= 0 )
316          pdims(1) = pdims(1) - 1
317       ENDDO
318       pdims(2) = numprocs / pdims(1)
319
320    ELSEIF ( npex /= -1  .AND.  npey /= -1 )  THEN
321
322!
323!--    Prescribed by user. Number of processors on the prescribed topology
324!--    must be equal to the number of PEs available to the job
325       IF ( ( npex * npey ) /= numprocs )  THEN
326          WRITE( message_string, * ) 'number of PEs of the prescribed ',   &
327              'topology (', npex*npey,') does not match & the number of ', &
328              'PEs available to the job (', numprocs, ')'
329          CALL message( 'init_pegrid', 'PA0221', 1, 2, 0, 6, 0 )
330       ENDIF
331       pdims(1) = npex
332       pdims(2) = npey
333
334    ELSE
335!
336!--    If the processor topology is prescribed by the user, the number of
337!--    PEs must be given in both directions
338       message_string = 'if the processor topology is prescribed by th' //  &
339                'e user& both values of "npex" and "npey" must be given' // &
340                ' in the &NAMELIST-parameter file'
341       CALL message( 'init_pegrid', 'PA0222', 1, 2, 0, 6, 0 )
342
343    ENDIF
344
345!
346!-- If necessary, set horizontal boundary conditions to non-cyclic
347    IF ( bc_lr /= 'cyclic' )  cyclic(1) = .FALSE.
348    IF ( bc_ns /= 'cyclic' )  cyclic(2) = .FALSE.
349
350
351!
352!-- Create the virtual processor grid
353    CALL MPI_CART_CREATE( comm_palm, ndim, pdims, cyclic, reorder, &
354                          comm2d, ierr )
355    CALL MPI_COMM_RANK( comm2d, myid, ierr )
356    WRITE (myid_char,'(''_'',I6.6)')  myid
357
358    CALL MPI_CART_COORDS( comm2d, myid, ndim, pcoord, ierr )
359    CALL MPI_CART_SHIFT( comm2d, 0, 1, pleft, pright, ierr )
360    CALL MPI_CART_SHIFT( comm2d, 1, 1, psouth, pnorth, ierr )
361!
362!-- In case of cyclic boundary conditions, a y-shift at the boundaries in
363!-- x-direction can be introduced via parameter y_shift. The shift is done
364!-- by modifying the processor grid in such a way that processors located
365!-- at the x-boundary communicate across it to processors with y-coordinate
366!-- shifted by y_shift relative to their own. This feature can not be used
367!-- in combination with an fft pressure solver. It has been implemented to
368!-- counter the effect of streak structures in case of cyclic boundary
369!-- conditions. For a description of these see Munters
370!-- (2016; dx.doi.org/10.1063/1.4941912)
371!--
372!-- Get coordinates of left and right neighbor on PE grid
373    IF ( y_shift /= 0 ) THEN
374
375       IF ( bc_lr /= 'cyclic'  .OR.  bc_ns /= 'cyclic' )  THEN
376          message_string = 'y_shift /= 0 is only allowed for cyclic ' //       &
377                           'boundary conditions in both directions '
378          CALL message( 'check_parameters', 'PA0467', 1, 2, 0, 6, 0 )
379       ENDIF
380       IF ( TRIM( psolver ) /= 'multigrid' .AND.                               &
381            TRIM( psolver ) /= 'multigrid_noopt')                              &
382       THEN
383          message_string = 'y_shift /= 0 requires a multigrid pressure solver '
384          CALL message( 'check_parameters', 'PA0468', 1, 2, 0, 6, 0 )
385       ENDIF
386
387       CALL MPI_CART_COORDS( comm2d, pright, ndim, rcoord, ierr )
388       CALL MPI_CART_COORDS( comm2d, pleft, ndim, lcoord, ierr )
389
390!
391!--    If the x(y)-coordinate of the right (left) neighbor is smaller (greater)
392!--    than that of the calling process, then the calling process is located on
393!--    the right (left) boundary of the processor grid. In that case,
394!--    the y-coordinate of that neighbor is increased (decreased) by y_shift.
395!--    The rank of the process with that coordinate is then inquired and the
396!--    neighbor rank for MPI_SENDRECV, pright (pleft) is set to it.
397!--    In this way, the calling process receives a new right (left) neighbor
398!--    for all future MPI_SENDRECV calls. That neighbor has a y-coordinate
399!--    of y+(-)y_shift, where y is the original right (left) neighbor's
400!--    y-coordinate. The modulo-operation ensures that if the neighbor's
401!--    y-coordinate exceeds the grid-boundary, it will be relocated to
402!--    the opposite part of the grid cyclicly.
403       IF ( rcoord(1) < pcoord(1) ) THEN
404          rcoord(2) = MODULO( rcoord(2) + y_shift, pdims(2) )
405          CALL MPI_CART_RANK( comm2d, rcoord, pright, ierr )
406       ENDIF
407
408       IF ( lcoord(1) > pcoord(1) ) THEN
409          lcoord(2) = MODULO( lcoord(2) - y_shift, pdims(2) )
410          CALL MPI_CART_RANK( comm2d, lcoord, pleft, ierr )
411       ENDIF
412    ENDIF
413!
414!-- Vertical nesting: store four lists that identify partner ranks to exchange
415!-- data
416    IF ( vnested )  CALL vnest_init_pegrid_rank
417
418!
419!-- Determine sub-topologies for transpositions
420!-- Transposition from z to x:
421    remain_dims(1) = .TRUE.
422    remain_dims(2) = .FALSE.
423    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dx, ierr )
424    CALL MPI_COMM_RANK( comm1dx, myidx, ierr )
425!
426!-- Transposition from x to y
427    remain_dims(1) = .FALSE.
428    remain_dims(2) = .TRUE.
429    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dy, ierr )
430    CALL MPI_COMM_RANK( comm1dy, myidy, ierr )
431
432
433!
434!-- Calculate array bounds along x-direction for every PE.
435    ALLOCATE( nxlf(0:pdims(1)-1), nxrf(0:pdims(1)-1), nynf(0:pdims(2)-1), &
436              nysf(0:pdims(2)-1) )
437
438    IF ( MOD( nx+1 , pdims(1) ) /= 0 )  THEN
439       WRITE( message_string, * ) 'x-direction: gridpoint number (',nx+1,') ',&
440                               'is not an& integral divisor of the number ',  &
441                               'processors (', pdims(1),')'
442       CALL message( 'init_pegrid', 'PA0225', 1, 2, 0, 6, 0 )
443    ELSE
444       nnx  = ( nx + 1 ) / pdims(1)
445       IF ( nnx*pdims(1) - ( nx + 1) > nnx )  THEN
446          WRITE( message_string, * ) 'x-direction: nx does not match the',    & 
447                       'requirements given by the number of PEs &used',       &
448                       '& please use nx = ', nx - ( pdims(1) - ( nnx*pdims(1) &
449                                      - ( nx + 1 ) ) ), ' instead of nx =', nx
450          CALL message( 'init_pegrid', 'PA0226', 1, 2, 0, 6, 0 )
451       ENDIF
452    ENDIF   
453
454!
455!-- Left and right array bounds, number of gridpoints
456    DO  i = 0, pdims(1)-1
457       nxlf(i)   = i * nnx
458       nxrf(i)   = ( i + 1 ) * nnx - 1
459    ENDDO
460
461!
462!-- Calculate array bounds in y-direction for every PE.
463    IF ( MOD( ny+1 , pdims(2) ) /= 0 )  THEN
464       WRITE( message_string, * ) 'y-direction: gridpoint number (',ny+1,') ', &
465                           'is not an& integral divisor of the number of',     &
466                           'processors (', pdims(2),')'
467       CALL message( 'init_pegrid', 'PA0227', 1, 2, 0, 6, 0 )
468    ELSE
469       nny  = ( ny + 1 ) / pdims(2)
470       IF ( nny*pdims(2) - ( ny + 1) > nny )  THEN
471          WRITE( message_string, * ) 'y-direction: ny does not match the',    &
472                       'requirements given by the number of PEs &used ',      &
473                       '& please use ny = ', ny - ( pdims(2) - ( nnx*pdims(2) &
474                                     - ( ny + 1 ) ) ), ' instead of ny =', ny
475          CALL message( 'init_pegrid', 'PA0228', 1, 2, 0, 6, 0 )
476       ENDIF
477    ENDIF   
478
479!
480!-- South and north array bounds
481    DO  j = 0, pdims(2)-1
482       nysf(j)   = j * nny
483       nynf(j)   = ( j + 1 ) * nny - 1
484    ENDDO
485
486!
487!-- Local array bounds of the respective PEs
488    nxl = nxlf(pcoord(1))
489    nxr = nxrf(pcoord(1))
490    nys = nysf(pcoord(2))
491    nyn = nynf(pcoord(2))
492    nzb = 0
493    nzt = nz
494    nnz = nz
495
496!
497!-- Set switches to define if the PE is situated at the border of the virtual
498!-- processor grid
499    IF ( nxl == 0 )   left_border_pe  = .TRUE.
500    IF ( nxr == nx )  right_border_pe = .TRUE.
501    IF ( nys == 0 )   south_border_pe = .TRUE.
502    IF ( nyn == ny )  north_border_pe = .TRUE.
503
504!
505!-- Calculate array bounds and gridpoint numbers for the transposed arrays
506!-- (needed in the pressure solver)
507!-- For the transposed arrays, cyclic boundaries as well as top and bottom
508!-- boundaries are omitted, because they are obstructive to the transposition
509
510!
511!-- 1. transposition  z --> x
512!-- This transposition is not neccessary in case of a 1d-decomposition along x
513    IF ( psolver == 'poisfft'  .OR.  calculate_spectra  .OR.                   &
514         use_synthetic_turbulence_generator )  THEN
515
516       IF ( pdims(2) /= 1 )  THEN
517          IF ( MOD( nz , pdims(1) ) /= 0 )  THEN
518             WRITE( message_string, * ) 'transposition z --> x:',              &
519                       '&nz=',nz,' is not an integral divisior of pdims(1)=',  &
520                                                                   pdims(1)
521             CALL message( 'init_pegrid', 'PA0230', 1, 2, 0, 6, 0 )
522          ENDIF
523       ENDIF
524
525       nys_x = nys
526       nyn_x = nyn
527       nny_x = nny
528       nnz_x = nz / pdims(1)
529       nzb_x = 1 + myidx * nnz_x
530       nzt_x = ( myidx + 1 ) * nnz_x
531       sendrecvcount_zx = nnx * nny * nnz_x
532
533    ENDIF
534
535
536    IF ( psolver == 'poisfft' )  THEN 
537!
538!--    2. transposition  x --> y
539       IF ( MOD( nx+1 , pdims(2) ) /= 0 )  THEN
540          WRITE( message_string, * ) 'transposition x --> y:',                 &
541                            '&nx+1=',nx+1,' is not an integral divisor of ',   &
542                            'pdims(2)=',pdims(2)
543          CALL message( 'init_pegrid', 'PA0231', 1, 2, 0, 6, 0 )
544       ENDIF
545
546       nnz_y = nnz_x
547       nzb_y = nzb_x
548       nzt_y = nzt_x
549       nnx_y = (nx+1) / pdims(2)
550       nxl_y = myidy * nnx_y
551       nxr_y = ( myidy + 1 ) * nnx_y - 1
552       sendrecvcount_xy = nnx_y * nny_x * nnz_y
553!
554!--    3. transposition  y --> z 
555!--    (ELSE:  x --> y  in case of 1D-decomposition along x)
556       nxl_z = nxl_y
557       nxr_z = nxr_y
558       nny_z = (ny+1) / pdims(1)
559       nys_z = myidx * nny_z
560       nyn_z = ( myidx + 1 ) * nny_z - 1
561       sendrecvcount_yz = nnx_y * nny_z * nnz_y
562
563       IF ( pdims(2) /= 1 )  THEN
564!
565!--       y --> z
566!--       This transposition is not neccessary in case of a 1d-decomposition
567!--       along x, except that the uptream-spline method is switched on
568          IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
569             WRITE( message_string, * ) 'transposition y --> z:',              &
570                               '& ny+1=',ny+1,' is not an integral divisor of',&
571                               ' pdims(1)=',pdims(1)
572             CALL message( 'init_pegrid', 'PA0232', 1, 2, 0, 6, 0 )
573          ENDIF
574
575       ELSE
576!
577!--       x --> y
578!--       This condition must be fulfilled for a 1D-decomposition along x
579          IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
580             WRITE( message_string, * ) 'transposition x --> y:',              &
581                               '& ny+1=',ny+1,' is not an integral divisor of',&
582                               ' pdims(1)=',pdims(1)
583             CALL message( 'init_pegrid', 'PA0233', 1, 2, 0, 6, 0 )
584          ENDIF
585
586       ENDIF
587
588    ENDIF
589
590!
591!-- Indices for direct transpositions z --> y (used for calculating spectra)
592    IF ( calculate_spectra )  THEN
593       IF ( MOD( nz, pdims(2) ) /= 0 )  THEN
594          WRITE( message_string, * ) 'direct transposition z --> y (needed ',  &
595                    'for spectra):& nz=',nz,' is not an integral divisor of ', &
596                    'pdims(2)=',pdims(2)
597          CALL message( 'init_pegrid', 'PA0234', 1, 2, 0, 6, 0 )
598       ELSE
599          nxl_yd = nxl
600          nxr_yd = nxr
601          nzb_yd = 1 + myidy * ( nz / pdims(2) )
602          nzt_yd = ( myidy + 1 ) * ( nz / pdims(2) )
603          sendrecvcount_zyd = nnx * nny * ( nz / pdims(2) )
604       ENDIF
605    ENDIF
606
607    IF ( psolver == 'poisfft'  .OR.  calculate_spectra )  THEN
608!
609!--    Indices for direct transpositions y --> x
610!--    (they are only possible in case of a 1d-decomposition along x)
611       IF ( pdims(2) == 1 )  THEN
612          nny_x = nny / pdims(1)
613          nys_x = myid * nny_x
614          nyn_x = ( myid + 1 ) * nny_x - 1
615          nzb_x = 1
616          nzt_x = nz
617          sendrecvcount_xy = nnx * nny_x * nz
618       ENDIF
619
620    ENDIF
621
622    IF ( psolver == 'poisfft' )  THEN
623!
624!--    Indices for direct transpositions x --> y
625!--    (they are only possible in case of a 1d-decomposition along y)
626       IF ( pdims(1) == 1 )  THEN
627          nnx_y = nnx / pdims(2)
628          nxl_y = myid * nnx_y
629          nxr_y = ( myid + 1 ) * nnx_y - 1
630          nzb_y = 1
631          nzt_y = nz
632          sendrecvcount_xy = nnx_y * nny * nz
633       ENDIF
634
635    ENDIF
636
637!
638!-- Arrays for storing the array bounds are needed any more
639    DEALLOCATE( nxlf , nxrf , nynf , nysf )
640
641
642!
643!-- Collect index bounds from other PEs (to be written to restart file later)
644    ALLOCATE( hor_index_bounds(4,0:numprocs-1) )
645
646    IF ( myid == 0 )  THEN
647
648       hor_index_bounds(1,0) = nxl
649       hor_index_bounds(2,0) = nxr
650       hor_index_bounds(3,0) = nys
651       hor_index_bounds(4,0) = nyn
652
653!
654!--    Receive data from all other PEs
655       DO  i = 1, numprocs-1
656          CALL MPI_RECV( ibuf, 4, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
657                         ierr )
658          hor_index_bounds(:,i) = ibuf(1:4)
659       ENDDO
660
661    ELSE
662!
663!--    Send index bounds to PE0
664       ibuf(1) = nxl
665       ibuf(2) = nxr
666       ibuf(3) = nys
667       ibuf(4) = nyn
668       CALL MPI_SEND( ibuf, 4, MPI_INTEGER, 0, myid, comm2d, ierr )
669
670    ENDIF
671
672
673#if defined( __print )
674!
675!-- Control output
676    IF ( myid == 0 )  THEN
677       PRINT*, '*** processor topology ***'
678       PRINT*, ' '
679       PRINT*, 'myid   pcoord    left right  south north  idx idy   nxl: nxr',&
680               &'   nys: nyn'
681       PRINT*, '------------------------------------------------------------',&
682               &'-----------'
683       WRITE (*,1000)  0, pcoord(1), pcoord(2), pleft, pright, psouth, pnorth, &
684                       myidx, myidy, nxl, nxr, nys, nyn
6851000   FORMAT (I4,2X,'(',I3,',',I3,')',3X,I4,2X,I4,3X,I4,2X,I4,2X,I3,1X,I3, &
686               2(2X,I4,':',I4))
687
688!
689!--    Receive data from the other PEs
690       DO  i = 1,numprocs-1
691          CALL MPI_RECV( ibuf, 12, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
692                         ierr )
693          WRITE (*,1000)  i, ( ibuf(j) , j = 1,12 )
694       ENDDO
695    ELSE
696
697!
698!--    Send data to PE0
699       ibuf(1) = pcoord(1); ibuf(2) = pcoord(2); ibuf(3) = pleft
700       ibuf(4) = pright; ibuf(5) = psouth; ibuf(6) = pnorth; ibuf(7) = myidx
701       ibuf(8) = myidy; ibuf(9) = nxl; ibuf(10) = nxr; ibuf(11) = nys
702       ibuf(12) = nyn
703       CALL MPI_SEND( ibuf, 12, MPI_INTEGER, 0, myid, comm2d, ierr )       
704    ENDIF
705#endif
706
707!
708!-- Determine the number of ghost point layers
709    IF ( ( scalar_advec == 'ws-scheme' .AND. .NOT. neutral ) .OR.             &
710         momentum_advec == 'ws-scheme' )  THEN
711       nbgp = 3
712    ELSE
713       nbgp = 1
714    ENDIF 
715
716!
717!-- Create a new MPI derived datatype for the exchange of surface (xy) data,
718!-- which is needed for coupled atmosphere-ocean runs.
719!-- First, calculate number of grid points of an xy-plane.
720    ngp_xy  = ( nxr - nxl + 1 + 2 * nbgp ) * ( nyn - nys + 1 + 2 * nbgp )
721    CALL MPI_TYPE_VECTOR( ngp_xy, 1, nzt-nzb+2, MPI_REAL, type_xy, ierr )
722    CALL MPI_TYPE_COMMIT( type_xy, ierr )
723
724    IF ( TRIM( coupling_mode ) /= 'uncoupled' .AND. .NOT. vnested )  THEN
725   
726!
727!--    Pass the number of grid points of the atmosphere model to
728!--    the ocean model and vice versa
729       IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
730
731          nx_a = nx
732          ny_a = ny
733
734          IF ( myid == 0 )  THEN
735
736             CALL MPI_SEND( nx_a, 1, MPI_INTEGER, numprocs, 1, comm_inter,  &
737                            ierr )
738             CALL MPI_SEND( ny_a, 1, MPI_INTEGER, numprocs, 2, comm_inter,  &
739                            ierr )
740             CALL MPI_SEND( pdims, 2, MPI_INTEGER, numprocs, 3, comm_inter, &
741                            ierr )
742             CALL MPI_RECV( nx_o, 1, MPI_INTEGER, numprocs, 4, comm_inter,  &
743                            status, ierr )
744             CALL MPI_RECV( ny_o, 1, MPI_INTEGER, numprocs, 5, comm_inter,  &
745                            status, ierr )
746             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, numprocs, 6,      &
747                            comm_inter, status, ierr )
748          ENDIF
749
750          CALL MPI_BCAST( nx_o, 1, MPI_INTEGER, 0, comm2d, ierr )
751          CALL MPI_BCAST( ny_o, 1, MPI_INTEGER, 0, comm2d, ierr ) 
752          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr )
753       
754       ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
755
756          nx_o = nx
757          ny_o = ny 
758
759          IF ( myid == 0 ) THEN
760
761             CALL MPI_RECV( nx_a, 1, MPI_INTEGER, 0, 1, comm_inter, status, &
762                            ierr )
763             CALL MPI_RECV( ny_a, 1, MPI_INTEGER, 0, 2, comm_inter, status, &
764                            ierr )
765             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, 0, 3, comm_inter, &
766                            status, ierr )
767             CALL MPI_SEND( nx_o, 1, MPI_INTEGER, 0, 4, comm_inter, ierr )
768             CALL MPI_SEND( ny_o, 1, MPI_INTEGER, 0, 5, comm_inter, ierr )
769             CALL MPI_SEND( pdims, 2, MPI_INTEGER, 0, 6, comm_inter, ierr )
770          ENDIF
771
772          CALL MPI_BCAST( nx_a, 1, MPI_INTEGER, 0, comm2d, ierr)
773          CALL MPI_BCAST( ny_a, 1, MPI_INTEGER, 0, comm2d, ierr) 
774          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr) 
775
776       ENDIF
777 
778       ngp_a = ( nx_a+1 + 2 * nbgp ) * ( ny_a+1 + 2 * nbgp )
779       ngp_o = ( nx_o+1 + 2 * nbgp ) * ( ny_o+1 + 2 * nbgp )
780
781!
782!--    Determine if the horizontal grid and the number of PEs in ocean and
783!--    atmosphere is same or not
784       IF ( nx_o == nx_a  .AND.  ny_o == ny_a  .AND.  &
785            pdims(1) == pdims_remote(1) .AND. pdims(2) == pdims_remote(2) ) &
786       THEN
787          coupling_topology = 0
788       ELSE
789          coupling_topology = 1
790       ENDIF 
791
792!
793!--    Determine the target PEs for the exchange between ocean and
794!--    atmosphere (comm2d)
795       IF ( coupling_topology == 0 )  THEN
796!
797!--       In case of identical topologies, every atmosphere PE has exactly one
798!--       ocean PE counterpart and vice versa
799          IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' ) THEN
800             target_id = myid + numprocs
801          ELSE
802             target_id = myid 
803          ENDIF
804
805       ELSE
806!
807!--       In case of nonequivalent topology in ocean and atmosphere only for
808!--       PE0 in ocean and PE0 in atmosphere a target_id is needed, since
809!--       data echxchange between ocean and atmosphere will be done only
810!--       between these PEs.   
811          IF ( myid == 0 )  THEN
812
813             IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' )  THEN
814                target_id = numprocs 
815             ELSE
816                target_id = 0
817             ENDIF
818
819          ENDIF
820
821       ENDIF
822
823    ENDIF
824
825!
826!-- Store partner grid point co-ordinates as lists.
827!-- Create custom MPI vector datatypes for contiguous data transfer
828    IF ( vnested )  CALL vnest_init_pegrid_domain
829
830#else
831
832!
833!-- Array bounds when running on a single PE (respectively a non-parallel
834!-- machine)
835    nxl = 0
836    nxr = nx
837    nnx = nxr - nxl + 1
838    nys = 0
839    nyn = ny
840    nny = nyn - nys + 1
841    nzb = 0
842    nzt = nz
843    nnz = nz
844
845    ALLOCATE( hor_index_bounds(4,0:0) )
846    hor_index_bounds(1,0) = nxl
847    hor_index_bounds(2,0) = nxr
848    hor_index_bounds(3,0) = nys
849    hor_index_bounds(4,0) = nyn
850
851!
852!-- Array bounds for the pressure solver (in the parallel code, these bounds
853!-- are the ones for the transposed arrays)
854    nys_x = nys
855    nyn_x = nyn
856    nzb_x = nzb + 1
857    nzt_x = nzt
858
859    nxl_y = nxl
860    nxr_y = nxr
861    nzb_y = nzb + 1
862    nzt_y = nzt
863
864    nxl_z = nxl
865    nxr_z = nxr
866    nys_z = nys
867    nyn_z = nyn
868
869#endif
870
871!
872!-- Calculate number of grid levels necessary for the multigrid poisson solver
873!-- as well as the gridpoint indices on each level
874    IF ( psolver(1:9) == 'multigrid' )  THEN
875
876!
877!--    First calculate number of possible grid levels for the subdomains
878       mg_levels_x = 1
879       mg_levels_y = 1
880       mg_levels_z = 1
881
882       i = nnx
883       DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
884          i = i / 2
885          mg_levels_x = mg_levels_x + 1
886       ENDDO
887
888       j = nny
889       DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
890          j = j / 2
891          mg_levels_y = mg_levels_y + 1
892       ENDDO
893
894       k = nz    ! do not use nnz because it might be > nz due to transposition
895                 ! requirements
896       DO WHILE ( MOD( k, 2 ) == 0  .AND.  k /= 2 )
897          k = k / 2
898          mg_levels_z = mg_levels_z + 1
899       ENDDO
900!
901!--    The optimized MG-solver does not allow odd values for nz at the coarsest
902!--    grid level
903       IF ( TRIM( psolver ) /= 'multigrid_noopt' )  THEN
904          IF ( MOD( k, 2 ) /= 0 )  mg_levels_z = mg_levels_z - 1
905       ENDIF
906
907       maximum_grid_level = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
908
909!
910!--    Find out, if the total domain allows more levels. These additional
911!--    levels are identically processed on all PEs.
912       IF ( numprocs > 1  .AND.  mg_switch_to_pe0_level /= -1 )  THEN
913
914          IF ( mg_levels_z > MIN( mg_levels_x, mg_levels_y ) )  THEN
915
916             mg_switch_to_pe0_level_l = maximum_grid_level
917
918             mg_levels_x = 1
919             mg_levels_y = 1
920
921             i = nx+1
922             DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
923                i = i / 2
924                mg_levels_x = mg_levels_x + 1
925             ENDDO
926
927             j = ny+1
928             DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
929                j = j / 2
930                mg_levels_y = mg_levels_y + 1
931             ENDDO
932
933             maximum_grid_level_l = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
934
935             IF ( maximum_grid_level_l > mg_switch_to_pe0_level_l )  THEN
936                mg_switch_to_pe0_level_l = maximum_grid_level_l - &
937                                           mg_switch_to_pe0_level_l + 1
938             ELSE
939                mg_switch_to_pe0_level_l = 0
940             ENDIF
941
942          ELSE
943             mg_switch_to_pe0_level_l = 0
944             maximum_grid_level_l = maximum_grid_level
945
946          ENDIF
947
948!
949!--       Use switch level calculated above only if it is not pre-defined
950!--       by user
951          IF ( mg_switch_to_pe0_level == 0 )  THEN
952             IF ( mg_switch_to_pe0_level_l /= 0 )  THEN
953                mg_switch_to_pe0_level = mg_switch_to_pe0_level_l
954                maximum_grid_level     = maximum_grid_level_l
955             ENDIF
956
957          ELSE
958!
959!--          Check pre-defined value and reset to default, if neccessary
960             IF ( mg_switch_to_pe0_level < mg_switch_to_pe0_level_l  .OR.  &
961                  mg_switch_to_pe0_level >= maximum_grid_level_l )  THEN
962                message_string = 'mg_switch_to_pe0_level ' // &
963                                 'out of range and reset to 0'
964                CALL message( 'init_pegrid', 'PA0235', 0, 1, 0, 6, 0 )
965                mg_switch_to_pe0_level = 0
966             ELSE
967!
968!--             Use the largest number of possible levels anyway and recalculate
969!--             the switch level to this largest number of possible values
970                maximum_grid_level = maximum_grid_level_l
971
972             ENDIF
973
974          ENDIF
975
976       ENDIF
977
978       ALLOCATE( grid_level_count(maximum_grid_level),                       &
979                 nxl_mg(0:maximum_grid_level), nxr_mg(0:maximum_grid_level), &
980                 nyn_mg(0:maximum_grid_level), nys_mg(0:maximum_grid_level), &
981                 nzt_mg(0:maximum_grid_level) )
982
983       grid_level_count = 0
984!
985!--    Index zero required as dummy due to definition of arrays f2 and p2 in
986!--    recursive subroutine next_mg_level
987       nxl_mg(0) = 0; nxr_mg(0) = 0; nyn_mg(0) = 0; nys_mg(0) = 0; nzt_mg(0) = 0
988
989       nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzt_l = nzt
990
991       DO  i = maximum_grid_level, 1 , -1
992
993          IF ( i == mg_switch_to_pe0_level )  THEN
994#if defined( __parallel )
995!
996!--          Save the grid size of the subdomain at the switch level, because
997!--          it is needed in poismg.
998             ind(1) = nxl_l; ind(2) = nxr_l
999             ind(3) = nys_l; ind(4) = nyn_l
1000             ind(5) = nzt_l
1001             ALLOCATE( ind_all(5*numprocs), mg_loc_ind(5,0:numprocs-1) )
1002             CALL MPI_ALLGATHER( ind, 5, MPI_INTEGER, ind_all, 5, &
1003                                 MPI_INTEGER, comm2d, ierr )
1004             DO  j = 0, numprocs-1
1005                DO  k = 1, 5
1006                   mg_loc_ind(k,j) = ind_all(k+j*5)
1007                ENDDO
1008             ENDDO
1009             DEALLOCATE( ind_all )
1010!
1011!--          Calculate the grid size of the total domain
1012             nxr_l = ( nxr_l-nxl_l+1 ) * pdims(1) - 1
1013             nxl_l = 0
1014             nyn_l = ( nyn_l-nys_l+1 ) * pdims(2) - 1
1015             nys_l = 0
1016!
1017!--          The size of this gathered array must not be larger than the
1018!--          array tend, which is used in the multigrid scheme as a temporary
1019!--          array. Therefore the subdomain size of an PE is calculated and
1020!--          the size of the gathered grid. These values are used in 
1021!--          routines pres and poismg
1022             subdomain_size = ( nxr - nxl + 2 * nbgp + 1 ) * &
1023                              ( nyn - nys + 2 * nbgp + 1 ) * ( nzt - nzb + 2 )
1024             gathered_size  = ( nxr_l - nxl_l + 3 ) * ( nyn_l - nys_l + 3 ) * &
1025                              ( nzt_l - nzb + 2 )
1026
1027#else
1028             message_string = 'multigrid gather/scatter impossible ' // &
1029                          'in non parallel mode'
1030             CALL message( 'init_pegrid', 'PA0237', 1, 2, 0, 6, 0 )
1031#endif
1032          ENDIF
1033
1034          nxl_mg(i) = nxl_l
1035          nxr_mg(i) = nxr_l
1036          nys_mg(i) = nys_l
1037          nyn_mg(i) = nyn_l
1038          nzt_mg(i) = nzt_l
1039
1040          nxl_l = nxl_l / 2 
1041          nxr_l = nxr_l / 2
1042          nys_l = nys_l / 2 
1043          nyn_l = nyn_l / 2 
1044          nzt_l = nzt_l / 2 
1045
1046       ENDDO
1047
1048!
1049!--    Temporary problem: Currently calculation of maxerror iin routine poismg crashes
1050!--    if grid data are collected on PE0 already on the finest grid level.
1051!--    To be solved later.
1052       IF ( maximum_grid_level == mg_switch_to_pe0_level )  THEN
1053          message_string = 'grid coarsening on subdomain level cannot be performed'
1054          CALL message( 'poismg', 'PA0236', 1, 2, 0, 6, 0 )
1055       ENDIF
1056
1057    ELSE
1058
1059       maximum_grid_level = 0
1060
1061    ENDIF
1062
1063!
1064!-- Default level 0 tells exchange_horiz that all ghost planes have to be
1065!-- exchanged. grid_level is adjusted in poismg, where only one ghost plane
1066!-- is required.
1067    grid_level = 0
1068
1069#if defined( __parallel )
1070!
1071!-- Gridpoint number for the exchange of ghost points (y-line for 2D-arrays)
1072    ngp_y  = nyn - nys + 1 + 2 * nbgp
1073
1074!
1075!-- Define new MPI derived datatypes for the exchange of ghost points in
1076!-- x- and y-direction for 2D-arrays (line)
1077    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_REAL, type_x,     &
1078                          ierr )
1079    CALL MPI_TYPE_COMMIT( type_x, ierr )
1080
1081    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_REAL, type_y, ierr )
1082    CALL MPI_TYPE_COMMIT( type_y, ierr )
1083!
1084!-- Define new MPI derived datatypes for the exchange of ghost points in
1085!-- x- and y-direction for 2D-INTEGER arrays (line) - on normal grid
1086    ALLOCATE( type_x_int(0:maximum_grid_level),                                &
1087              type_y_int(0:maximum_grid_level) )
1088
1089    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_INTEGER,          &
1090                          type_x_int(0), ierr )
1091    CALL MPI_TYPE_COMMIT( type_x_int(0), ierr )
1092
1093    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_INTEGER, type_y_int(0), ierr )
1094    CALL MPI_TYPE_COMMIT( type_y_int(0), ierr )
1095!
1096!-- Calculate gridpoint numbers for the exchange of ghost points along x
1097!-- (yz-plane for 3D-arrays) and define MPI derived data type(s) for the
1098!-- exchange of ghost points in y-direction (xz-plane).
1099!-- Do these calculations for the model grid and (if necessary) also
1100!-- for the coarser grid levels used in the multigrid method
1101    ALLOCATE ( ngp_xz(0:maximum_grid_level),                                   &
1102               ngp_xz_int(0:maximum_grid_level),                               &
1103               ngp_yz(0:maximum_grid_level),                                   &
1104               ngp_yz_int(0:maximum_grid_level),                               &
1105               type_xz(0:maximum_grid_level),                                  &
1106               type_xz_int(0:maximum_grid_level),                              &
1107               type_yz(0:maximum_grid_level),                                  &
1108               type_yz_int(0:maximum_grid_level) )
1109
1110    nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzb_l = nzb; nzt_l = nzt
1111
1112!
1113!-- Discern between the model grid, which needs nbgp ghost points and
1114!-- grid levels for the multigrid scheme. In the latter case only one
1115!-- ghost point is necessary.
1116!-- First definition of MPI-datatypes for exchange of ghost layers on normal
1117!-- grid. The following loop is needed for data exchange in poismg.f90.
1118!
1119!-- Determine number of grid points of yz-layer for exchange
1120    ngp_yz(0) = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1121
1122!
1123!-- Define an MPI-datatype for the exchange of left/right boundaries.
1124!-- Although data are contiguous in physical memory (which does not
1125!-- necessarily require an MPI-derived datatype), the data exchange between
1126!-- left and right PE's using the MPI-derived type is 10% faster than without.
1127    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz(0), &
1128                          MPI_REAL, type_xz(0), ierr )
1129    CALL MPI_TYPE_COMMIT( type_xz(0), ierr )
1130
1131    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz(0), ngp_yz(0), MPI_REAL, type_yz(0), &
1132                          ierr ) 
1133    CALL MPI_TYPE_COMMIT( type_yz(0), ierr )
1134
1135!
1136!-- Define data types for exchange of 3D Integer arrays.
1137    ngp_yz_int(0) = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1138
1139    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz_int(0),   &
1140                          MPI_INTEGER, type_xz_int(0), ierr )
1141    CALL MPI_TYPE_COMMIT( type_xz_int(0), ierr )
1142
1143    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz_int(0), ngp_yz_int(0), MPI_INTEGER,     &
1144                          type_yz_int(0), ierr )
1145    CALL MPI_TYPE_COMMIT( type_yz_int(0), ierr )
1146
1147!
1148!-- Definition of MPI-datatypes for multigrid method (coarser level grids)
1149    IF ( psolver(1:9) == 'multigrid' )  THEN
1150!   
1151!--    Definition of MPI-datatyoe as above, but only 1 ghost level is used
1152       DO  i = maximum_grid_level, 1 , -1
1153!
1154!--       For 3D-exchange on different multigrid level, one ghost point for
1155!--       REAL arrays, two ghost points for INTEGER arrays
1156          ngp_xz(i) = (nzt_l - nzb_l + 2) * (nxr_l - nxl_l + 3)
1157          ngp_yz(i) = (nzt_l - nzb_l + 2) * (nyn_l - nys_l + 3)
1158
1159          ngp_xz_int(i) = (nzt_l - nzb_l + 2) * (nxr_l - nxl_l + 3)
1160          ngp_yz_int(i) = (nzt_l - nzb_l + 2) * (nyn_l - nys_l + 3)
1161!
1162!--       MPI data type for REAL arrays, for xz-layers
1163          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+3, nzt_l-nzb_l+2, ngp_yz(i),       &
1164                                MPI_REAL, type_xz(i), ierr )
1165          CALL MPI_TYPE_COMMIT( type_xz(i), ierr )
1166
1167!
1168!--       MPI data type for INTEGER arrays, for xz-layers
1169          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+3, nzt_l-nzb_l+2, ngp_yz_int(i),   &
1170                                MPI_INTEGER, type_xz_int(i), ierr )
1171          CALL MPI_TYPE_COMMIT( type_xz_int(i), ierr )
1172
1173!
1174!--       MPI data type for REAL arrays, for yz-layers
1175          CALL MPI_TYPE_VECTOR( 1, ngp_yz(i), ngp_yz(i), MPI_REAL, type_yz(i), &
1176                                ierr )
1177          CALL MPI_TYPE_COMMIT( type_yz(i), ierr )
1178!
1179!--       MPI data type for INTEGER arrays, for yz-layers
1180          CALL MPI_TYPE_VECTOR( 1, ngp_yz_int(i), ngp_yz_int(i), MPI_INTEGER,  &
1181                                type_yz_int(i), ierr )
1182          CALL MPI_TYPE_COMMIT( type_yz_int(i), ierr )
1183
1184
1185!--       For 2D-exchange of INTEGER arrays on coarser grid level, where 2 ghost
1186!--       points need to be exchanged.
1187          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+5, 2, nyn_l-nys_l+5, MPI_INTEGER,          &
1188                                type_x_int(i), ierr )
1189          CALL MPI_TYPE_COMMIT( type_x_int(i), ierr )
1190
1191
1192          CALL MPI_TYPE_VECTOR( 2, nyn_l-nys_l+5, nyn_l-nys_l+5, MPI_INTEGER,          &
1193                                type_y_int(i), ierr )
1194          CALL MPI_TYPE_COMMIT( type_y_int(i), ierr )
1195
1196          nxl_l = nxl_l / 2
1197          nxr_l = nxr_l / 2
1198          nys_l = nys_l / 2
1199          nyn_l = nyn_l / 2
1200          nzt_l = nzt_l / 2
1201
1202       ENDDO
1203
1204    ENDIF
1205
1206#endif
1207
1208#if defined( __parallel )
1209!
1210!-- Setting of flags for inflow/outflow/nesting conditions.
1211    IF ( pleft == MPI_PROC_NULL )  THEN
1212       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1213          inflow_l  = .TRUE.
1214       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1215          outflow_l = .TRUE.
1216       ELSEIF ( bc_lr == 'nested' )  THEN
1217          nest_bound_l = .TRUE.
1218       ELSEIF ( bc_lr == 'forcing' )  THEN
1219          force_bound_l = .TRUE.
1220       ENDIF
1221    ENDIF
1222 
1223    IF ( pright == MPI_PROC_NULL )  THEN
1224       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1225          outflow_r = .TRUE.
1226       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1227          inflow_r  = .TRUE.
1228       ELSEIF ( bc_lr == 'nested' )  THEN
1229          nest_bound_r = .TRUE.
1230       ELSEIF ( bc_lr == 'forcing' )  THEN
1231          force_bound_r = .TRUE.
1232       ENDIF
1233    ENDIF
1234
1235    IF ( psouth == MPI_PROC_NULL )  THEN
1236       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1237          outflow_s = .TRUE.
1238       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1239          inflow_s  = .TRUE.
1240       ELSEIF ( bc_ns == 'nested' )  THEN
1241          nest_bound_s = .TRUE.
1242       ELSEIF ( bc_ns == 'forcing' )  THEN
1243          force_bound_s = .TRUE.
1244       ENDIF
1245    ENDIF
1246
1247    IF ( pnorth == MPI_PROC_NULL )  THEN
1248       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1249          inflow_n  = .TRUE.
1250       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1251          outflow_n = .TRUE.
1252       ELSEIF ( bc_ns == 'nested' )  THEN
1253          nest_bound_n = .TRUE.
1254       ELSEIF ( bc_ns == 'forcing' )  THEN
1255          force_bound_n = .TRUE.
1256       ENDIF
1257    ENDIF
1258
1259!
1260!-- Broadcast the id of the inflow PE
1261    IF ( inflow_l )  THEN
1262       id_inflow_l = myidx
1263    ELSE
1264       id_inflow_l = 0
1265    ENDIF
1266    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1267    CALL MPI_ALLREDUCE( id_inflow_l, id_inflow, 1, MPI_INTEGER, MPI_SUM, &
1268                        comm1dx, ierr )
1269
1270!
1271!-- Broadcast the id of the recycling plane
1272!-- WARNING: needs to be adjusted in case of inflows other than from left side!
1273    IF ( NINT( recycling_width / dx ) >= nxl  .AND. &
1274         NINT( recycling_width / dx ) <= nxr )  THEN
1275       id_recycling_l = myidx
1276    ELSE
1277       id_recycling_l = 0
1278    ENDIF
1279    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1280    CALL MPI_ALLREDUCE( id_recycling_l, id_recycling, 1, MPI_INTEGER, MPI_SUM, &
1281                        comm1dx, ierr )
1282
1283!
1284!-- Broadcast the id of the outflow PE and outflow-source plane
1285    IF ( turbulent_outflow )  THEN
1286
1287       IF ( outflow_r )  THEN
1288          id_outflow_l = myidx
1289       ELSE
1290          id_outflow_l = 0
1291       ENDIF
1292       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1293       CALL MPI_ALLREDUCE( id_outflow_l, id_outflow, 1, MPI_INTEGER, MPI_SUM, &
1294                           comm1dx, ierr )
1295
1296       IF ( NINT( outflow_source_plane / dx ) >= nxl  .AND. &
1297            NINT( outflow_source_plane / dx ) <= nxr )  THEN
1298          id_outflow_source_l = myidx
1299       ELSE
1300          id_outflow_source_l = 0
1301       ENDIF
1302       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1303       CALL MPI_ALLREDUCE( id_outflow_source_l, id_outflow_source, 1, &
1304                           MPI_INTEGER, MPI_SUM, comm1dx, ierr )
1305
1306    ENDIF
1307
1308    CALL location_message( 'finished', .TRUE. )
1309
1310#else
1311    IF ( bc_lr == 'dirichlet/radiation' )  THEN
1312       inflow_l  = .TRUE.
1313       outflow_r = .TRUE.
1314    ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1315       outflow_l = .TRUE.
1316       inflow_r  = .TRUE.
1317    ENDIF
1318
1319    IF ( bc_ns == 'dirichlet/radiation' )  THEN
1320       inflow_n  = .TRUE.
1321       outflow_s = .TRUE.
1322    ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1323       outflow_n = .TRUE.
1324       inflow_s  = .TRUE.
1325    ENDIF
1326#endif
1327
1328!
1329!-- At the inflow or outflow, u or v, respectively, have to be calculated for
1330!-- one more grid point.
1331    IF ( inflow_l .OR. outflow_l .OR. nest_bound_l .OR. force_bound_l )  THEN
1332       nxlu = nxl + 1
1333    ELSE
1334       nxlu = nxl
1335    ENDIF
1336    IF ( inflow_s .OR. outflow_s .OR. nest_bound_s .OR. force_bound_s )  THEN
1337       nysv = nys + 1
1338    ELSE
1339       nysv = nys
1340    ENDIF
1341
1342!
1343!-- Allocate wall flag arrays used in the multigrid solver
1344    IF ( psolver(1:9) == 'multigrid' )  THEN
1345
1346       DO  i = maximum_grid_level, 1, -1
1347
1348           SELECT CASE ( i )
1349
1350              CASE ( 1 )
1351                 ALLOCATE( wall_flags_1(nzb:nzt_mg(i)+1,         &
1352                                        nys_mg(i)-1:nyn_mg(i)+1, &
1353                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1354
1355              CASE ( 2 )
1356                 ALLOCATE( wall_flags_2(nzb:nzt_mg(i)+1,         &
1357                                        nys_mg(i)-1:nyn_mg(i)+1, &
1358                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1359
1360              CASE ( 3 )
1361                 ALLOCATE( wall_flags_3(nzb:nzt_mg(i)+1,         &
1362                                        nys_mg(i)-1:nyn_mg(i)+1, &
1363                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1364
1365              CASE ( 4 )
1366                 ALLOCATE( wall_flags_4(nzb:nzt_mg(i)+1,         &
1367                                        nys_mg(i)-1:nyn_mg(i)+1, &
1368                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1369
1370              CASE ( 5 )
1371                 ALLOCATE( wall_flags_5(nzb:nzt_mg(i)+1,         &
1372                                        nys_mg(i)-1:nyn_mg(i)+1, &
1373                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1374
1375              CASE ( 6 )
1376                 ALLOCATE( wall_flags_6(nzb:nzt_mg(i)+1,         &
1377                                        nys_mg(i)-1:nyn_mg(i)+1, &
1378                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1379
1380              CASE ( 7 )
1381                 ALLOCATE( wall_flags_7(nzb:nzt_mg(i)+1,         &
1382                                        nys_mg(i)-1:nyn_mg(i)+1, &
1383                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1384
1385              CASE ( 8 )
1386                 ALLOCATE( wall_flags_8(nzb:nzt_mg(i)+1,         &
1387                                        nys_mg(i)-1:nyn_mg(i)+1, &
1388                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1389
1390              CASE ( 9 )
1391                 ALLOCATE( wall_flags_9(nzb:nzt_mg(i)+1,         &
1392                                        nys_mg(i)-1:nyn_mg(i)+1, &
1393                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1394
1395              CASE ( 10 )
1396                 ALLOCATE( wall_flags_10(nzb:nzt_mg(i)+1,        &
1397                                        nys_mg(i)-1:nyn_mg(i)+1, &
1398                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1399
1400              CASE DEFAULT
1401                 message_string = 'more than 10 multigrid levels'
1402                 CALL message( 'init_pegrid', 'PA0238', 1, 2, 0, 6, 0 )
1403
1404          END SELECT
1405
1406       ENDDO
1407
1408    ENDIF
1409
1410 END SUBROUTINE init_pegrid
Note: See TracBrowser for help on using the repository browser.